Can't set default value for argument when argument has :inapt-if

[nvimtor]

I have an argument:

(transient-define-argument helmel--transient-arg-release-get-output ()
  "Select the output format of a release Helm Get."
  :class 'transient-option
  :transient t
  :key "-o"
  :description "Output format"
  :argument "--output="
  :always-read t
  :choices '("table" "json" "yaml")
  :inapt-if
  (lambda ()
    (let ((args (helmel--transient-get-args)))
      (not (or (member "metadata" args) (member "values" args))))))

and this is the prefix that contains this argument:

(transient-define-prefix helmel-release-get ()
  "Get information for a release."
  :refresh-suffixes t
  :value (lambda ()
            (message "refreshed?")
            '("--output=yaml"))
  :incompatible '(("hooks" "manifest" "metadata" "notes" "values"))
  [:description helmel--transient-describe-title
                ""]
  [:description
   (lambda ()
     (let* ((entry (transient-scope))
            (release-name (helmel-get-releases-column-value "NAME" entry)))
       (format "Get ... for release: %s\n" (propertize release-name 'face 'bold))))
   ["Options"
    ("-r" "Revision" "--revision=")
    (helmel--transient-arg-release-get-output)]
   ["Resource"
    ("h" "Hooks"    "hooks")
    ("m" "Manifest" "manifest")
    ("M" "Metadata" "metadata")
    ("n" "Notes"    "notes")
    ("v" "Values"   "values")]]
  [[(helmel--transient-suffix-release-get)]]
  (interactive)
  (transient-setup 'helmel-release-get nil nil :scope (transient-scope)))

Even though I set --output=yaml in :value, whenever :inapt-if's condition returns nil, --output is not set to yaml automatically.

I don't know if this is expected and, if it is, how can I set a default value for an argument that has an :inept-if?

:value seems to work for any other argument though, like --revision=, just fine.

Thanks.

[tarsius]

A better test case:

Details

(defvar demo-inapt nil)

(transient-define-suffix demo-toggle-inapt ()
  :key "t"
  :description (##format "Toggle inapt (%s)" demo-inapt)
  (interactive)
  (setq demo-inapt (not demo-inapt)))

(transient-define-argument demo--a ()
  :class 'transient-option
  :key "a"
  :description "Honor inapt"
  :argument "--a="
  :choices '("1" "2")
  :inapt-if-non-nil 'demo-inapt)

(transient-define-argument demo--b ()
  :class 'transient-option
  :key "b"
  :description "Ignore inapt"
  :argument "--b="
  :choices '("1" "2"))

(transient-define-argument demo--c ()
  :class 'transient-option
  :key "c"
  :description "Honor inapt via group"
  :argument "--c="
  :choices '("1" "2"))

(transient-define-prefix demo ()
  :refresh-suffixes t
  :transient-suffix t
  :value '("--a=1" "--b=1" "--c=1")
  [(demo-toggle-inapt)
   (demo--a)
   (demo--b)
   (transient-echo-arguments)]
  [:inapt-if-non-nil demo-inapt
   (demo--c)])

I've pushed something to the 407 branch, but I'll have to think about it some more before pushing to main.

[tarsius]

Also #316.

[nvimtor]

Hey @tarsius

Wow, that was quick, thanks for the update.

I want to test the changes and report back but I can't see the 407 branch in this repository. Is it somewhere else or not public?

Thanks

[tarsius]

Ah sorry, had not pushed yet.

[tarsius]

I've just pushed support for this and the related #316 and #364. The whole commit series deals with this, but the more interesting commits include b4edb63, 6322fc7, b44be23 and e144e9c, where it all comes together.

Here's the test prefix used to test the features requested in the three topics:

Details

;; -*- lexical-binding: t -*-

(defun demo-predicate ()
  (transient-arg-value "-a" (transient-get-value)))

(transient-define-argument demo--a ()
  :class 'transient-switch
  :description "Predicate switch"
  :argument "-a")

(transient-define-argument demo--b ()
  :class 'transient-switch
  :description "if switch"
  :argument "-b"
  :if #'demo-predicate)

(transient-define-argument demo--c ()
  :class 'transient-switch
  :description "inapt-if-not switch"
  :argument "-c"
  :inapt-if-not #'demo-predicate)

(transient-define-argument demo--d ()
  :class 'transient-option
  :description "inapt-if-not option"
  :argument "--d="
  :choices '("1" "2")
  :inapt-if-not #'demo-predicate)

(transient-define-prefix demo ()
  :refresh-suffixes t
  :transient-suffix t
  :value '("-a" "-b" "-c" "--d=1" "-e" "-f" "-g")
  [("a" demo--a)
   ( :info "(placeholder)"
     :face transient-inapt-suffix
     :if-not demo-predicate)
   ("b" demo--b)
   ("c" demo--c)
   ("d" demo--d)]
  [("e" "regular switch" "-e")
   ("f" "level 7 switch" "-f" :level 7)
   ("g" "level 0 switch" "-g" :level 0)]
  [(:info* (##format "Extended arguments: %s" (transient--get-extended-value)))
   (:info* (##format "Active arguments:   %s" (transient-get-value)))
   (transient-echo-arguments)])